shellinabox/configure.ac

AC_PREREQ(2.57)

dnl This is the one location where the authoritative version number is stored
AC_INIT(shellinabox, 2.5, markus@shellinabox.com)
VCS_REVISION=87
AC_SUBST(VCS_REVISION)
AC_DEFINE_UNQUOTED(VCS_REVISION, "${VCS_REVISION}",
                   [Most recent revision number in the version control system])

dnl Set up autoconf/automake for building C libraries and binaries with GCC
AM_INIT_AUTOMAKE
AM_CONFIG_HEADER(config.h)
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LIBTOOL
AC_SUBST(LIBTOOL_DEPS)
AC_C_CONST
AC_PROG_GCC_TRADITIONAL

dnl Check for header files that do not exist on all platforms
AC_CHECK_HEADERS([libutil.h pthread.h sys/prctrl.h utmp.h utmpx.h])

dnl Most systems require linking against libutil.so in order to get login_tty()
AC_CHECK_FUNCS(login_tty, [],
               [AC_CHECK_LIB(util, login_tty,
                [LIBS="-lutil $LIBS"
                 AC_DEFINE(HAVE_LOGIN_TTY)])])

dnl We prefer ptsname_r(), but will settle for ptsname() if necessary
AC_TRY_LINK([#ifndef _XOPEN_SOURCE
             #define _XOPEN_SOURCE
             #endif
             #ifndef _GNU_SOURCE
             #define _GNU_SOURCE
             #endif
             #include <stdlib.h>],
            [ptsname_r(0, 0, 0);],
            [AC_DEFINE(HAVE_PTSNAME_R, 1,
                     Define to 1 if you have a re-entrant version of ptsname)])

dnl We automatically detect SSL support, but allow users to disable it
AC_ARG_ENABLE(ssl,
              [  --disable-ssl             if available at built-time, support for SSL
                            connections will be enabled. It can still be
                            disabled at run-time, either on the daemon's
                            command line or if the operating system does not
                            have the OpenSSL libraries available.])

dnl We automatically detect PAM support, but allow users to disable it
AC_ARG_ENABLE(pam,
              [  --disable-pam             PAM support is necessary in order to authenticate
                            users for running programs other than their default
                            login shell.])

dnl We try to always use dlopen() instead of linking libraries dynamically, as
dnl this reduces the hard run-time dependencies that our binary has. But we
dnl allow users to disable this feature.
AC_ARG_ENABLE(runtime-loading,
              [  --disable-runtime-loading ShellInABox will try to load the OpenSSL, and PAM
                            libraries at run-time, if it has been compiled with
                            support for these libraries, and if the operating
                            system supports dynamic loading of libraries. This
                            allows you to install the same binary on different
                            systems independent of whether they have OpenSSL
                            and PAM enabled.  If you would rather directly link
                            these libraries into the binary, thus making them a
                            hard dependency, then disable runtime-loading.])

dnl Only test for OpenSSL headers, if not explicitly disabled
if test "x$enable_ssl" != xno; then
  AC_CHECK_HEADERS([openssl/bio.h openssl/err.h openssl/ssl.h])
fi

dnl Only test for PAM headers, if not explicitly disabled
if test "x$enable_pam" != xno; then
  AC_CHECK_HEADERS([security/pam_appl.h security/pam_client.h                 \
                    security/pam_misc.h ])
fi

dnl Only test for dlopen(), if not explicitly disabled. Add required libdl.so
dnl library if necessary. Also, if dlopen() is not available on this system,
dnl explicitly disable runtime loading.
if test "x$enable_runtime_loading" != xno; then
  AC_CHECK_FUNCS(dlopen, [],
                 [AC_CHECK_LIB(dl, dlopen,
                               [LIBS="-ldl $LIBS"
                                AC_DEFINE(HAVE_DLOPEN)],
                               [enable_runtime_loading=no])])
fi

dnl If runtime loading has been disabled, add OpenSSL and PAM as hard
dnl dependencies.
if test "x$enable_runtime_loading" == xno; then
  dnl Link against OpenSSL libraries, unless SSL support has been disabled
  if test "x$enable_ssl" != xno; then
    AC_CHECK_HEADER(openssl/ssl.h, [LIBS="-lssl $LIBS"])
  fi

  dnl Link against PAM libraries, unless PAM support has been disabled
  if test "x$enable_pam" != xno; then
    AC_CHECK_HEADER(security/pam_appl.h, [LIBS="-lpam $LIBS"])
    AC_CHECK_HEADER(security/pam_misc.h, [LIBS="-lpam_misc $LIBS"])
  fi
fi

dnl Generate output files
AC_CONFIG_FILES([Makefile])
AC_OUTPUT